tb期货程序化交易平台(期货程序化交易 tb)

说实话，这个系统我也考察过一段时间，个人确实还不错的，后期没用上，是因为我头疼那震荡期间的打脸，被虐的心累了，就把它给放下了，它的有效性是毋庸置疑的的，世界排名前三的系统，你们懂的。我这边直接引用的就是TB论坛里穿堂风的代码了，他分享了现成代码，我也不用再自己去写一遍的，要是我再改下各参数名或变量名，就说是自己写的，这也没意义的。我们还是直接引用穿堂风大神写的代码了，如下：

Params

Numeric K1(0.5);//声明数值参数k1，初值为0.5，其实就是上轨系数，当然不喜欢这个数值的可以根据自己统计结果改的。//

Numeric K2(0.5);//声明数值参数k2，初值0.5，即下轨系数。//

Numeric Mday(1);//声明数值参数Mday，初值为1.//

Numeric Nday(1);//声明数值参数Nday，初值为1.//

Numeric lots(1);//声明数值参数lots，初值1，其实就是买卖手数。//

Numeric offset(0);//声明数值参数offset，初值0。//

Vars

Numeric BuyRange(0);//声明数值变量BuyRange，初值为0，即上轨幅度。//

Numeric SellRange(0);//声明数值变量SellRange，初值为0，即下轨幅度。//

Numeric BuyTrig(0);//声明数值变量BuyTrig，初值为0.//

Numeric SellTrig(0);//声明数值变量SellTrig，初值为0.//

Numeric HH;//声明数值变量HH。//

Numeric LL;//声明数值变量LL。//

Numeric HC;//声明数值变量HC。//

Numeric LC;//声明数值变量LC。//

Numeric i_offset;//声明数值变量i_offset。//

Numeric BuyPosition;//声明数值变量BuyPosition，即买入价格。//

Numeric SellPosition;//声明数值变量SellPosition，即卖出价格。//

Begin

If(CurrentBar > 45*Max(Mday,Nday))//使用的是5分钟周期，其它的周期自己做相应修改。其实我试过直接写成CurrentBar>0,测试结果没什么影响的，你一想都知道，真正交易的超级图表，你不可能从第一根k线开始，所以索引值不影响的，当然这可能是逻辑更严谨的。//

{

i_offset = offset*MinMove*PriceScale;//其实就是之前一直说的最小跳动价固定公式了，这里就多添加了参数offset而已，即可以让你滑点委托成交。//

HH = Highest(HighD(1),Mday);//变量HH值即为昨天最高价。//

HC = Highest(CloseD(1),Mday);//变量HC值即为昨天的收盘价。//

LL = Lowest(LowD(1),Mday);//变量LL值为昨天最低价。//

LC = Lowest(CloseD(1),Mday);//变量LC值为昨天收盘价。跟变量HC一样的。//

If((HH - LC) >= (HC - LL))//假如昨天最高价-昨天收盘价 >= 昨天收盘价-昨天最低价。//

{

SellRange = HH - LC;//变量SellRange = 昨天最高价-昨天收盘价。//

}

Else //就是上边if条件不成立的情况了。//

{

SellRange = HC - LL; //变量SellRange = 昨天收盘价 - 昨天最低价。//

}

HH = Highest(HighD(1),Nday);//同上，HH=昨天最高价。//

HC = Highest(CloseD(1),Nday);//同上，HC=昨天收盘价。//

LL = Lowest(LowD(1),Nday);//同上，LL=昨天最低价。//

LC = Lowest(CloseD(1),Nday); //同上，LC=昨天最低价。//

If((HH - LC) >= (HC - LL)) // 同上解读的。//

{

BuyRange = HH - LC;//变量BuyRange = 昨天最高价-昨天收盘价。//

}

Else//同上解读。//

{

BuyRange = HC - LL;//变量BuyRange = 昨天收盘价 - 昨天最低价。//

}

BuyTrig = K1*BuyRange;//根据上面求得的，直接代入解读了。//

SellTrig = K2*SellRange;//其实你看这两个公式都知道，上下幅度系数是一致的。//

BuyPosition = OpenD(0)+BuyTrig;//上轨，即开盘价 + BuyTrig。//

SellPosition = OpenD(0)-SellTrig;//下轨，即开盘价 - SellTrig。//

PlotNumeric("BuyPosition",BuyPosition);//画线上轨。//

PlotNumeric("SellPosition",SellPosition);//画线下轨。//

If(MarketPosition == 0)//当没有持仓情况下。//

{

If(High>=BuyPosition)//假如当前高价 >= 上轨。//

{

Buy(lots,Max(Open,BuyPosition)+i_offset); //开仓买1手，价格为取开盘价与上轨对比的较大值，再加上设置的滑点数了。//

Return;//返回，不执行了。//

}

If(Low<=SellPosition) //假如当前低价 <= 下轨。//

{

SellShort(lots,Min(Open,SellPosition)-i_offset);//开仓卖出1手，价格为取开盘价与下轨对比的较小值，再加上设置的滑点数了。//

Return;//返回，不执行了。//

}

}

If(MarketPosition == -1)//当前持空单的情况下。//

{

If(High>=BuyPosition)//假如当前高价 >=上轨。//

{

Buy(lots,Max(Open,BuyPosition)+i_offset);//平仓买1手，价格为取开盘价与上轨对比的较大值，再加上设置的滑点数了。//

Return;//返回，不执行了。//

}

}

If(MarketPosition == 1)//当持多单情况。//

{

If(Low<=SellPosition)//假如当前低价 <= 下轨。//

{

SellShort(lots,Min(Open,SellPosition)-i_offset); //平仓卖出1手，价格为取开盘价与下轨对比的较小值，再加上设置的滑点数了。//

Return;//返回，不执行了。//

}

}

}

End

结果不错吧，这个是很简单的一个系统，根据昨天的最高价、最低价与收盘价的差值，把上下轨系数确定了，突破上轨就买入，突破下轨就卖出，止损止盈就是上下轨了。很有名的一个程序化交易系统，喜欢的朋友，可以自己观察全面了解了，再用它的。